Excelで2つの日付の差分を文字列で返す関数

2つの日付の差分を文字列で返します。

'===== ===== ===== ===== ===== ===== ===== ===== =====
' 2つの日付の差分を取る
'===== ===== ===== ===== ===== ===== ===== ===== =====
Public Function myDateDiff(ByVal argDate1 As Date, ByVal argDate2 As Date) As String
    myDateDiff = ""
    Dim diffSec As Long
    Dim isMinus As Boolean
    isMinus = False
    
    '差異(秒単位)
    diffSec = DateDiff("s", argDate1, argDate2)
    If diffSec < 0 Then
        isMinus = True
        diffSec = Abs(diffSec)
    End If
    
    Dim myDay As Integer
    Dim myHour As Integer
    Dim myMin As Integer
    Dim mySec As Integer
    
    myDay = diffSec \ (24& * 60 * 60)
    myHour = (diffSec Mod (24& * 60 * 60)) \ (60& * 60)
    myMin = (diffSec Mod (60& * 60)) \ 60&
    mySec = (diffSec Mod 60)
    
    myDateDiff = IIf(isMinus, "-", "") & Format(myDay, "##0") & "日 " & Format(myHour, "#0") & "時間" & Format(myMin, "#0") & "分" & Format(mySec, "#0") & "秒"
End Function

数字12桁の文字列からからDate型に変換可能な文字列へ変換します

'===== ===== ===== ===== ===== ===== ===== ===== =====
' 数字12桁の文字列からからDate型に変換可能な文字列へ
'===== ===== ===== ===== ===== ===== ===== ===== =====
Public Function toDate(ByVal argStr) As String
    toDate = ""
    If Len(argStr) <> 12 Then
        Exit Function
    End If
    
    Dim myDate As String
    myDate = CDate(Mid(argStr, 1, 4) & "/" & Mid(argStr, 5, 2) & "/" & Mid(argStr, 7, 2) & " " & Mid(argStr, 9, 2) & ":" & Mid(argStr, 11, 2) & ":00")
    
    toDate = myDate
End Function